長上下影例子-自己做 AUTO(x) 自動買賣指標步驟
自己動手做 AUTO(x) "自動買賣指標" 步驟係好容易既事, 方法如下:
我們先假定我要用一個 BP-ATUO9 名來做指標~
首先, 睇下 indicator builder 內有無相同指標,
如果有而你係無用的, 可以先行刪除~
刪除後, 便可以正式重新建立一個新指標, 按 New
記得係一定要使用 BP-AUTO9 為名, 當然你可以用外掛支援的名便可~
再將你建立好的程式抄進之內便可以:
(小秘訣: 建立程式碼時, 先使用Note Pad 寫好先, 再 Copy 進內便可以)
今次例子:
{長上下影買賣 20110311}
nPlan:=Input("Leg's Level =1, =2",1,2,2);
nConf:=Input("After confirmed-:",0,1,1);
nVol:=Input("Volume:",1,9999,1);
nDirect:=Input("Up&Dn=0, Up=1, Dn=2:",0,2,0);
{------- PLan 1 = 1/2 長影方法 -----------------}
upLegL1:= Abs(C > (H-L)/2+L) AND Abs(O > (H-L)/2+L) AND V >= nVol;
upLegL2:= Abs(C > (H-L)/3*2+L) AND Abs(O > (H-L)/3*2+L)AND V >= nVol;
{}
dnLegL1:= Abs(C < (H-L)/2+L) AND Abs(O < (H-L)/2+L) AND V >= nVol;
dnLegL2:= Abs(C < (H-L)/3*1+L) AND Abs(O < (H-L)/3*1+L)AND V >= nVol;
{}
nBuy1:=If(nPlan=1, upLegL1, upLegL2 ) ;
nSell1:=If(nPlan=1, dnLegL1, dnLegL2 ) ;
{}
BuyMethod:= If(nConf=0, nBuy1 , Ref( nBuy1,-1) AND C >=Ref(L,-1) );
SellMethod:= If(nConf=0,nSell1, Ref( nSell1 ,-1) AND C <= Ref(H,-1) );
{}
buy:= If( nDirect=0 OR nDirect=1, BuyMethod,0);
sell:= If( nDirect=0 OR nDirect=2,SellMethod,0);
{}
RetVal:=If(buy=1,0.3, If(Sell=1,0.03,0.00));
Retval;
nVol/100000;
nConf/100000;
nDirect/100000;
附件為原碼檔案:
及可用MS import 檔案:
:A_119: :A_100: 運用 BP 外掛寫自動買賣指標的指定格式如下:
{名稱一定要用 BP-AUTO(x)}
buy:= ( 買入方法 );
sell:=( 沽出方法 );
{}
RetVal:=If(buy=1,0.3, If(Sell=1,0.03,0.00));
Retval
e.g. 收市價升跌穿10 天平衡移動線 買賣
{名稱一定要用 BP-AUTO(x)}
buy:= ( Cross(C,mov(C,10,S)) );
sell:=( Cross(mov(C,10,S),C) );
{}
RetVal:=If(buy=1,0.3, If(Sell=1,0.03,0.00));
Retval
其它請睇說明書PDF:
『最佳拍檔』外掛精靈 使用說明文件
http://www.bp-system.com/discuz/viewthread.php?tid=4180&page=1#pid28584
2# admin
Thank you, 好有用，其實我一直都想做d陰陽燭型態的自動買賣， auto9 正好合用，希望自己真係的起心肝落實做啦! :A_127: 阿布依建議加入陰陽燭選項:
即
長上影陰燭先沽
長下影陽燭先楂
{長上下影買賣 20110919}
nPlan:=Input("Leg's Level =1, =2",1,2,2);
nWBcandle:=Input("Leg's Candle White / Black On=1, Off=0",0,1,1);
nCanPnt:=Input("High - Low >= Points:",1,1000,30);
nConf:=Input("After confirmed-:",0,1,1);
nVol:=Input("Volume:",1,9999,1);
nDirect:=Input("Up&Dn=0, Up=1, Dn=2:",0,2,0);
{------- PLan 1 = 1/2 長影方法 -----------------}
upLegL1:= Abs(C > (H-L)/2+L) AND Abs(O > (H-L)/2+L) AND V >= nVol;
upLegL2:= Abs(C > (H-L)/3*2+L) AND Abs(O > (H-L)/3*2+L)AND V >= nVol;
dnLegL1:= Abs(C < (H-L)/2+L) AND Abs(O < (H-L)/2+L) AND V >= nVol;
dnLegL2:= Abs(C < (H-L)/3*1+L) AND Abs(O < (H-L)/3*1+L)AND V >= nVol;
nBuy2:=If(nPlan=1, upLegL1, upLegL2 ) AND Abs(H-L) >= nCanPntandC >= O ;
nSell2:=If(nPlan=1, dnLegL1, dnLegL2 ) AND Abs(H-L) >= nCanPnt and O >= C ;
nBuy1:=if( nWBcandle=1, nBuy2 , If(nPlan=1, upLegL1, upLegL2 ) AND Abs(H-L) >= nCanPnt );
nSell1:=if( nWBcandle=1, nSell2 , If(nPlan=1, dnLegL1, dnLegL2 ) AND Abs(H-L) >= nCanPnt ) ;
{}
{方法}
BuyMethod:= If(nConf=0, nBuy1 , Ref( nBuy1,-1) AND C >=Ref(L,-1) );
SellMethod:= If(nConf=0,nSell1, Ref( nSell1 ,-1) AND C <= Ref(H,-1) );
{}
buy:= If( nDirect=0 OR nDirect=1, BuyMethod,0);
sell:= If( nDirect=0 OR nDirect=2,SellMethod,0);
{}
{}
RetVal:=If(buy=1,0.3, If(Sell=1,0.03,0.00));
Retval;
nVol/100000;
nCanPnt/100000;
nConf/100000;
nDirect/100000;
C/100000
附件為原碼檔案:
及可用MS import 檔案:
:A_119: 你地慢用...我不負責測試成效.....
想問matthew.......我依你方法,調用了自己sigal入auto9.....但auto9 只出1欄數字(0.000)....其他如auto7/auto5,會出4,5欄數字...
我的auto9 正常嗎?..... thx.... 正常, 因為其它數字係跟你自己安排, 須再輸入於後面, 如上面個例子:
Retval;
nVol/100000;
nCanPnt/100000;
nConf/100000;
nDirect/100000;
C/100000
數值除 100000 係特意用 "0." 後數值顯示,
你只要將你想要顯示的數值, 順排於之後便可以,
但第 1個數字必須為 Retval , 因為這個是買賣訊號用。
:A_127:
admin 发表于 2013-12-21 12:05 static/image/common/back.gif
正常, 因為其它數字係跟你自己安排, 須再輸入於後面, 如上面個例子:
咁樣如只有一個數值,是否已可做到買賣?...因驚搞多錯多.....{:4_339:} :A_052:
係, 外掛程式只會掃瞄第1個數值, 所以其它無影响~
页:
[1]